Вниманию участников! Данный форум теперь является архивом и вскором времени здесь нельзя будет создавать новых тем! Просьба всем для общения и создания новых тем перейти на наш новый форум: http://amxmodx.su/

test_string <произвольный_текст>

/* Stringy Tasks
    *
    * (c) 2007, Orangutanz
    * This file is provided as is (no warranties).
    */

#include <amxmodx>
#include <fakemeta>

#define PLUGINNAME  "Stringy Tasks"
#define VERSION     "1.0.0"
#define AUTHORS     "Orangutanz"

public plugin_init()
{
       register_plugin( PLUGINNAME, VERSION, AUTHORS ) // регистрация плагина
       register_clcmd( "test_string", "str_test" ) // регистрация клиентской команды test_string
}

public str_test( id ) // обработчик команды test_string
{
       // id - индекс игрока (от 1 до 32), который выполнил данную команду

       new string[ 64 ]
       read_argv( 1, string, sizeof( string ) - 1 ) // считываем первый параметр команды

       new param[ 3 ]
       param[ 0 ] = EncodeText( "Hello" )
       param[ 1 ] = EncodeText( string )
       param[ 2 ] = EncodeText( "Goodbye" )

       set_task( 1.0, "string_task", 0, param, sizeof( param ) ) // через 1.0 сек. будет вызвана функция string_task()
         
       return PLUGIN_HANDLED // если этого не сделать, то в консоль будет выдано сообщение о неверной команде
}

public string_task( const param[ 3 ] )
{
       new string[ 64 ]

       for ( new i; i < sizeof( param ); i++ )
       {
           DecodeText( param[i], string, sizeof( string ) - 1 )
           client_print( 0, 3, string )
       }
}

EncodeText( const text[] )
{
       return engfunc( EngFunc_AllocString, text )
}

DecodeText( const text, string[], const length )
{
       global_get( glb_pStringBase, text, string, length )
}