Вниманию участников! Данный форум теперь является архивом и вскором времени здесь нельзя будет создавать новых тем! Просьба всем для общения и создания новых тем перейти на наш новый форум: http://amxmodx.su/

/********************************  CHECK TK FUNCTION *******************************/
check_v(kIndex)
{
  if(is_user_connected(kIndex))
   {
   // Check to see if player has any TK's left then ban or warn
   new kName[32]
   new kAuthid[32]
   new kIP[32]
   new Date[64]
   new BanInfo[256]
   get_user_name(kIndex, kName, 31)
   get_user_authid(kIndex, kAuthid, 31)
   get_user_ip(kIndex, kIP, 31, 1)
   get_time("%m/%d/%y %H:%M:%S", Date, 63)
   new kTeam = get_user_team(kIndex)
   // Set TK hud msg format
   set_hudmessage((kTeam == 1) ? 140 : 0, (kTeam == 2) ? 100 : 0, (kTeam == 2) ? 200 : 0, 0.05, 0.50, 2, 0.1, 4.0, 0.02, 0.02, -1)
    
   new atac_tk_before_ban = get_pcvar_num(pv_atac_tk_before_ban)
   new atac_banvia = get_pcvar_num(pv_atac_banvia)
   new atac_bantime = get_pcvar_num(pv_atac_bantime)
   new atac_hudmessages = get_pcvar_num(pv_atac_hudmessages)
   new atac_amxban = get_pcvar_num(pv_atac_amxban)
    
   update_stat_text(kIndex)
    
   // Check if user needs to be banned
   if(KickMe[kIndex] >= atac_tk_before_ban && is_user_connected(kIndex))
    {
    new userid = get_user_userid(kIndex)
    if(is_user_bot(kIndex))
     {
     atac_banvia = 3
    }
    if(atac_banvia == 1 || atac_banvia == 2)
     {
     if(atac_bantime)
      {
      client_print(kIndex, 1, "%L", kIndex, "TIME_BANNED_MSG", atac_bantime)
      atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_VOLATION_TIME_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_bantime) : client_print(0, 3, "%L", LANG_PLAYER, "TK_VOLATION_TIME_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_bantime)
      formatex(BanInfo, 255, "%L", LANG_SERVER, "TIME_BAN_LOG_MSG", Date, kName, kIP, kAuthid,KickMe[kIndex], atac_tk_before_ban, atac_bantime)
     }
     else
      {
      client_print(kIndex, 1, "%L", kIndex, "PERMA_BANNED_MSG")
      atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_VOLATION_PERMA_MSG", KickMe[kIndex], atac_tk_before_ban, kName) : client_print(0, 3, "%L", LANG_PLAYER, "TK_VOLATION_PERMA_MSG", KickMe[kIndex], atac_tk_before_ban, kName)
      formatex(BanInfo, 255, "%L", LANG_SERVER, "PERMA_BAN_LOG_MSG", Date, kName, kIP, kAuthid,KickMe[kIndex], atac_tk_before_ban)
     }
     //Reomved due to steam equal("4294967295", kAuthid)
     if(atac_banvia == 2) // If LAN or IP ban via IP
      {
      if(atac_amxban != 1)
       {
       server_cmd("addip %i %s;writeip;kick #%d", atac_bantime, kIP, userid)
      }
      else
       {
       server_cmd("amx_banip %i %s Max Team Kill Violation %i/%i", atac_bantime, kIP, KickMe[kIndex], get_pcvar_num(pv_atac_tk_before_ban))
      }
     }
     else
      {
      if( atac_amxban != 1)
       {
       server_cmd("banid %i #%d kick;writeid", atac_bantime, userid)
      }
      else
       {
       server_cmd("amx_ban %i %s Max Team Kill Violation %i/%i", atac_bantime, kAuthid, KickMe[kIndex], get_pcvar_num(pv_atac_tk_before_ban))
      }
     }
    }
    else if(atac_banvia == 3)
     {
     client_print(kIndex, 1, "%L", kIndex, "KICK_MSG")
     atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_VOLATION_KICK_MSG", KickMe[kIndex], atac_tk_before_ban, kName) : client_print(0, 3, "%L", LANG_PLAYER, "TK_VOLATION_KICK_MSG", KickMe[kIndex], atac_tk_before_ban, kName)
     formatex(BanInfo, 255, "%L", LANG_SERVER, "KICK_LOG_MSG", Date, kName, kIP, kAuthid, KickMe[kIndex], atac_tk_before_ban)
     server_cmd("kick #%d", userid)
    }
    if(get_pcvar_num(pv_atac_log) == 1)
     {
     new filepath[64], filename[128]
     get_configsdir( filepath, 63 )
     format(filepath, 63, "%s/atac", filepath)
     formatex(filename, 127, "%s/atac.log", filepath)
     write_file(filename, BanInfo, -1)
    }
   }
   else
    {
    if(atac_banvia == 1 || atac_banvia == 2)
     {
     if(atac_bantime)
      {
      atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_TIME_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban, atac_bantime) : client_print(0, 3, "%L", LANG_PLAYER, "TK_TIME_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban, atac_bantime)
     }
     else
      {
      atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_PERMA_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban) : client_print(0, 3, "%L", LANG_PLAYER, "TK_PERMA_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban)
     }
    }
    else if(atac_banvia == 3)
     {
     atac_hudmessages ? ShowSyncHudMsg(0, g_HudSyncBan, "%L", LANG_PLAYER, "TK_KICK_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban) : client_print(0, 3, "%L", LANG_PLAYER, "TK_KICK_MSG", KickMe[kIndex], atac_tk_before_ban, kName, atac_tk_before_ban)
    }
   }
  }
}